/*=========================================================
  
  Catena disposta lungo una curva parametrica
      
  Metodi e Modelli Matematici          
  Gian Marco Todesco, novembre 2007
  http://archinet.uniroma3.it/mate/metodi/2007

=========================================================*/

#include "colors.inc"
#include "textures.inc"


//
// camera, sorgente di luce, piano
//

camera {  
  location 0.7*<3,3,-4>
  right x*image_width/image_height
  look_at <0,-0.5,0>
  angle 40
}

light_source { <1,4,-2> color 1 }

light_source { <-1,2,-6> color 0.5 shadowless}
light_source { < 1,2,-6> color 0.5 shadowless}


plane {
  y,-1
  pigment {
    checker White Orange   
    scale 4
  }
} 




// 
// Curva(T); T=[0,1]; cerchio
// 
#macro Curva(T) 
  #local Phi = 2*pi*T;  
  <cos(Phi), 0,sin(Phi)>  
#end


//
// Definisco l'anello della catena un semplice cerchio
//
#declare Anello = torus {
  0.2,0.05 
  texture { 
    pigment {Cyan} 
    finish {specular 0.7 roughness 0.05}
  }
}

//
// Calcolo la lunghezza totale della curva (fra T=0 e T=1)
//
#declare LunghezzaCurva = 0.0;
#declare N = 10000; // approssimo la curva come una spezzata fatta da N segmenti
#declare I = 0;
#while(I<N)
  #local Segmento = Curva(I/N) - Curva((I+1)/N);
  #declare LunghezzaCurva = LunghezzaCurva + vlength(Segmento); 
  #declare I=I+1;
#end
#debug concat("Lunghezza curva = ", str(LunghezzaCurva, 10,5), "\n")



//
// creo la catena
//

union {

  #local T0 = 0;
  
  #local OldP = Curva(0);
  
  #local N = floor(LunghezzaCurva/0.3);
  #local N = N + mod(N,2);
  #local D = LunghezzaCurva / N;

  #local I = 0;
  #while(I<N)
    
    #local P = Curva(T0);
    #while(vlength(P-OldP)<D)
      #local T0 = T0 + 0.0001;
      #local P = Curva(T0);
    #end
    #local OldP = P;   
    
    
    #local H = 0.00001;
    #local DP = vnormalize(Curva(T0+H) - Curva(T0-H));
  
    #local E0 = DP;
    #local E2 = vnormalize(vcross(E0,y));
  
    #local E1 = vcross(E2,E0);

    object  {
      Anello 
      rotate 90*I*x
      
      matrix <
        E0.x,E0.y,E0.z,
        E1.x,E1.y,E1.z,
        E2.x,E2.y,E2.z,
        P.x,P.y,P.z
      >
      
    }

    #local I=I+1;
  #end
}