/*=========================================================
  
  Curva parametrica disegnata con sfere e cilindri
  
    
  Metodi e Modelli Matematici          
  Gian Marco Todesco, ottobre 2007
  http://archinet.uniroma3.it/mate/metodi/2007

=========================================================*/

#include "colors.inc"
#include "textures.inc"

camera {  
  location <0,0,-8>
  right x*image_width/image_height
  look_at <0,0,0>
  angle 30
}

light_source { <2,7,-7> color 1 }

default {
  finish {
    ambient 0.4
  }
}


background {White}

plane {
  -z,0
  pigment {
    checker Orange White  
    scale 0.25
  }
}

//
// Definizione della Curva T : [0,1] -> <X,Y,Z>
//
#macro Curva(T) 
  #local Phi0 = 2*pi*T; 
  #local Phi1 = Phi0 * 11;
  #local R0 = 1.0;
  #local R1 = 0.25;   
  (R0*<cos(Phi0), sin(Phi0), 0> + R1*<cos(Phi1), sin(Phi1), 0>)
#end

//
// Disegno con sfere e cilindri
//
union {
  #local N = 5000; 
  #local SemiSpessore = 0.03;

  #local OldP = Curva(0);
  sphere {OldP,SemiSpessore} 
  #local I = 1;
  #while(I<N)
    
    #local P = Curva(I/(N-1));
    sphere { P, SemiSpessore }
    cylinder {OldP, P, SemiSpessore }

    #local OldP = P;    
    #local I = I + 1;
  #end

  texture {
    pigment {VioletRed}
    finish { specular 0.8 roughness 0.01}
  }
}