/*=========================================================
  
  Curva parametrica nello spazio: spirale sulla sfera
  con cambiamento di spessore
      
  Metodi e Modelli Matematici          
  Gian Marco Todesco, novembre 2007
  http://archinet.uniroma3.it/mate/metodi/2007

=========================================================*/

#include "colors.inc"
#include "textures.inc"
#include "stones.inc"


camera {
  location  0.6*<1,3.5,-6>
  right     x*image_width/image_height
  look_at 0
  angle 45
}

default {
  finish {
    ambient 0.4  
    diffuse 0.6
  }
}

light_source { <8,10,-5> color 1 }

plane {
  y,-1 
  texture { T_Stone3 }
}

//
// Definisco la curva Curva : [0,1] -> R3
//
#macro Curva(T)
  #local Phi = 5*2*pi*T;
  #local Theta = pi * (0.01 + 0.98*T);
  #local R = sin(Theta);
  #local Y = cos(Theta);
  <R*cos(Phi),Y,R*sin(Phi)>
#end

// spessore
#macro Spessore(T)
  T*(1-T)*4*0.08
#end


// 
// La "disegno" con sfere e tronchi di cono
//
union {
  #local N = 1000;
  #local I = 0;
  #while(I<N)
    #local T0 = I/N;
    #local T1 = (I+1)/N;
    
    #local P0 = Curva(T0);
    #local P1 = Curva(T1);
    #local R0 = Spessore(T0);
    #local R1 = Spessore(T1);
    
    sphere {P0, R0}
    cone {P0,R0,P1,R1}    
    #local I=I+1;
  #end
  sphere {Curva(1),Spessore(1)}

  sphere {
    0,1
    texture {
      pigment {rgbt<0.3,0.6,0.7,0.5>}
      finish {Metal}
    }
  }

  texture { Gold_Metal }
  
  
  rotate -30*z 
  rotate 30*y
}