/*=========================================================
  
  Curva parametrica disegnata con sfere e cilindri e con
  sistema di rif. mobile lungo la curva
  
    
  Metodi e Modelli Matematici          
  Gian Marco Todesco, ottobre 2007
  http://archinet.uniroma3.it/mate/metodi/2007

=========================================================*/


#include "colors.inc"
#include "textures.inc"

camera {  
  location 0.7*<0,6,-4>
  right x*image_width/image_height
  look_at <0,0,0>
  angle 40
}

light_source { <1,4,-2> color 1 }

light_source { <-1,2,-6> color 1 shadowless}
light_source { < 1,2,-6> color 1 shadowless}


plane {
  y,-4
  pigment {
    checker White Orange   
    
  }
} 


#macro Curva(T) 
  #local Phi = 4*pi*T;  
  #local Theta = 1.5*Phi;
  #local R = 1+0.2*sin(Theta);
  #local Y = 0.2*cos(Theta);    
  <cos(Phi)*R, Y,sin(Phi)*R>
  
#end


union {

  #local N = 100;
  #local I = 0;
  #while(I<N)
  
    #local T0 = I/N;
    #local P = Curva(T0);
    #local H = 0.00001;
    #local DP = vnormalize(Curva(T0+H) - Curva(T0-H));
  
    #local E0 = DP;
  
    #local E1 = y;
    #local E1 = vnormalize(E1 - vdot(E1,E0)*E0);

    #local E2 = vcross(E0,E1);
     
    sphere {P,0.06 texture {Copper_Metal}}
    cone {P,0.02, P+0.3*E1, 0 texture {Gold_Metal}}
    cone {P,0.02, P+0.3*E2, 0 texture {Brass_Metal}}
  
    #local I=I+1;
  #end
  
  
  #local Spessore = 0.03;
    
  #local N = 1000;
    
  #local OldP = Curva(0);
  sphere {OldP, Spessore }

  #local I = 1;
  #while(I<N)
    
    #local T = I/(N-1);
    #local P = Curva(T);
      
    sphere { P, Spessore }
    cylinder { P,OldP, Spessore }

    #local OldP = P;    
    
    #local I = I + 1;
  #end

  rotate 20*y
  texture {
    pigment {White}
    finish {diffuse 0.3 ambient 0.4}
  }


}