/*=========================================================
  
  Una semplice scena composta da due tetraedri, una scritta
  e una terna di assi cartesiani.
  La terna di assi e' definita nel file "assi.inc"
  
    
  Metodi e Modelli Matematici          
  Gian Marco Todesco, ottobre 2007
  http://archinet.uniroma3.it/mate/metodi/2007

=========================================================*/

#include "colors.inc"
#include "textures.inc"


// questo e' il punto di vista 
camera {
 location <1,5,-7> // mi trovo dalle parti dell'asse z negativo
 look_at <0,0,0>   // e guardo l'origine
                   
}


light_source {
  <0,10,-5> color 2
}

plane {
  y, -1
  pigment { color rgb 1}
}

// Vertici del tetraedro
#declare P0 = < -1,-1,-1>;
#declare P1 = <  1, 1,-1>;
#declare P2 = <  1,-1, 1>;
#declare P3 = < -1, 1, 1>;

// dichiarazione del tetradro
#declare Tetraedro = union {    
  // vertici
  sphere {P0, .2}
  sphere {P1, .2}
  sphere {P2, .2}
  sphere {P3, .2} 
  // spigoli
  cylinder {P0,P1,0.1}
  cylinder {P1,P2,0.1}
  cylinder {P2,P0,0.1}
  cylinder {P0,P3,0.1}
  cylinder {P1,P3,0.1}
  cylinder {P2,P3,0.1}    
  // facce
  triangle {P0,P1,P2}
  triangle {P0,P1,P3}
  triangle {P1,P2,P3}
  triangle {P2,P0,P3}
  
  // Il tetraedro e' color arancio metallico
  texture { 
    pigment {Orange}
    finish {Metal} 
  }
}

// Posiziono un primo tetraedro
object { 
  Tetraedro 
}

// e un secondo ruotato di 90 gradi attorno all'asse verticale
object { 
  Tetraedro 
  rotate y*90 
}


// Una scritta
text {
  ttf             
  "crystal.ttf",  
  "Stella Octangula",
  0.1, // profondita' dell'estrusione
  0 // spazio extra fra i caratteri
  
  scale 0.75 // rimpicciolisco il tutto
  translate <-2,0,-3> // e lo posiziono nel punto giusto
  
   
  no_shadow  // non voglio che la scritta faccia ombra  
  texture {Gold_Metal}  // colore dorato  
}


// piazzo gli assi, un po' spostati per bellezza
union {
  #include "assi.inc"
  
  translate <-2,1,2>
}