/*=========================================================
  
  Sfera di lego 
    
  Metodi e Modelli Matematici          
  Gian Marco Todesco, gennaio 2008
  http://archinet.uniroma3.it/mate/metodi/2007

=========================================================*/

#include "colors.inc"
#include "textures.inc"

#version 3.5;

global_settings {
  assumed_gamma 1
}

camera {
  location 12*<2,4,-3>
  right image_width/image_height*x
  look_at y
  angle 60
}

light_source {<2,30,-70>, color 1}
light_source {<-3,30,-10>, color 1}

plane {y,-10 pigment {White transmit 0.5}}


#declare Mattone = union {
  box {-1,1}
  #local D = 0.5;
  cylinder {0,y*1.2,0.3 translate <-D,0,-D>}
  cylinder {0,y*1.2,0.3 translate < D,0,-D>}
  cylinder {0,y*1.2,0.3 translate <-D,0, D>}
  cylinder {0,y*1.2,0.3 translate < D,0, D>}
  
  scale 0.98
  pigment {LimeGreen}
}

#declare N = 20;
#declare Radius = 20;
#declare I = 0;
#while(I<N)
  #declare J = 0;
  #while(J<N)
    #declare K = 0;
    #while(K<N)
     
      #local X = I*2 - (N-1);
      #local Y = J*2 - (N-1);
      #local Z = K*2 - (N-1);
      #if(X*X+Y*Y+Z*Z < Radius*Radius)
        object {Mattone translate <X,Y,Z>}
      #end
      #declare K=K+1;
    #end
    #declare J=J+1;
  #end
  #declare I=I+1;
#end