/*=========================================================
  
  Superficie parametrica
      
  Metodi e Modelli Matematici          
  Gian Marco Todesco, novembre 2007
  http://archinet.uniroma3.it/mate/metodi/2007

=========================================================*/

#include "colors.inc"
#include "textures.inc"


camera {  
  location <2,2,-4>
  right x*image_width/image_height
  look_at <0,0.0,0>
  angle 40
}

light_source { <1,4,-2> color 1 }

light_source { <-1,2,-6> color 0.5 shadowless}
light_source { < 1,2,-6> color 0.5 shadowless}


// cielo
sky_sphere {
  pigment {
    gradient y
    color_map { [0.0 color rgb <0.7,0.7,1.0>] [1.0 color blue 0.5] }
  }
}

// un pavimento con un fondo irregolare
plane {
  y,-1 
  pigment{ color rgb <0.9,0.75,0.2>}
  normal { 
    crackle 0.5 // bump depth
    scale .1 
  }
}

// un po' di nebbia
fog {
  fog_type   2
  distance   5
  color      rgb 0.6 // gray
  fog_offset 0.1
  fog_alt    0.5
}

//
// Surface(T,S); T=[0,1], S=[0,1]
//
#macro Surface(T,S) 
  <T*2-1, 0.5*sin(3*T*pi)*sin(3*S*pi), S*2-1>
#end

//
// Dichiaro e inizializzo la tabella Vertici che comprende 
// gli N*M punti della griglia con cui approssimo la superficie
//

#declare N = 40;
#declare M = 40;
#declare Vertici = array[N][M];
#declare I=0;
#while(I<N)  
  #local T = I/(N-1);  
  #local J = 0;
  #while(J<M)
    #local S = J/(M-1);        
    #declare Vertici[I][J] = Surface(T,S);    
    #local J=J+1;
  #end
  #declare I=I+1;
#end


//
// Disegno gli assi
//
#declare Axis = union {
  cylinder {-x,x,0.01}
  cone {x,0.02, x*1.2,0}
}

object {Axis pigment {Red}}
object {Axis rotate 90*z pigment {Green}}
object {Axis rotate -90*y pigment {Blue}}


//
// Disegno la griglia
//
union {
  
  #local R0 = 0.007; // raggio sfere
  #local R1 = 0.006; // raggio cilindri
  #local I = 0;
  #while(I<N)    
    #local J = 0;
    #while(J<M)

      sphere { Vertici[I][J], R0  }
      #if(J>0) cylinder { Vertici[I][J], Vertici[I][J-1], R1 } #end
      #if(I>0) cylinder { Vertici[I][J], Vertici[I-1][J], R1 } #end
 
      #local J=J+1;
    #end    
    #local I=I+1;
  #end

  texture {
    pigment {White}
    finish {diffuse 0.3 ambient 0.4}
  }
}