// 
// es10.pov
// griglia di anelli incatenati
//
// Gian Marco Todesco :: todesco@toonz.com
// per il Liceo Copernico, 13 novembre 2009
//

#include "colors.inc"
#include "textures.inc"

// telecamera virtuale
camera {
  location 8*<0,0,-10>
  look_at <0,0,0>
  angle 20
}

// luce
light_source { <3,4,-4> color rgb <2,1.8,1.8> }

light_source { <-3,1,-20> color rgb 0.8 }

// muro
plane { 
  -z,-1 
  pigment { White }
}


// anello di catena, costituito da due semi-tori e due cilindri
// NOTA BENE: e' disposto in maniera diversa rispetto a es6.pov:
// e' verticale e spostato verso destra

#declare ChainRing = union {
  #local R0 = 0.3;   // semi-distanza fra i cilindri = raggio principale del toro
  #local R1 = 0.1;  // semi-spessore = raggio minore del toro
  #local D = 0.3;    // semi-distanza fra i due semi tori
  // Nota: la lunghezza complessiva dell'anello di catena
  // e' 2*(D+R0)
  #local HalfRing = difference {torus {R0,R1 } plane {x,0}}
  // semi-toro di dx
  object {HalfRing translate D*x}
  // semi-toro di sx
  object {HalfRing rotate 180*y translate -D*x}
  // cilindri di collegamento
  cylinder {-D*x,D*x,R1 translate -R0*z }
  cylinder {-D*x,D*x,R1 translate  R0*z }
  // texture
  texture {Silver_Metal}
  
  rotate x*90
  translate x
}

// griglia

union {
  
  #local N = 10; // numero di righe
  #local M = 10; // numero di colonne

  // ciclo sulle righe
  #local I = 0;
  #while(I<N)
    
    // ciclo sulle colonne
    #local J = 0;
    #while(J<M)
      
      // calcolo le coordinate del centro dell'anello (I,J)-esimo
      #local X = (J-(M-1)/2)*2 + mod(I,2);
      #local Z = (I-(N-1)/2)*sqrt(3);

      union {    

        // l'anello (I,J)-esimo
        torus { 0.8,0.2 
          texture {
            pigment {Orange}
            finish {Metal}
          }
        }   
      
        // incateno l'anello
        object { ChainRing } // verso dx
        object { ChainRing rotate  60*y } // dx-basso
        object { ChainRing rotate -60*y } // dx-alto
        
        // sposto il tutto nella posizione giusta
        translate <X,0,Z> 
      }       
      
      // fine del ciclo sulle colonne
      #local J=J+1;
    #end
    
    // fine del ciclo sulle righe
    #local I=I+1;
  #end
  
  // ruoto tutta la griglia
  rotate 90*x
}