// 
// es11.pov
//
// Sistema di assi cartesiani e scritte
// Curva parametrica nello spazio
//
// Gian Marco Todesco :: todesco@toonz.com
// per il Liceo Copernico, 6 novembre 2009
//


#include "colors.inc"
#include "textures.inc"

// punto di vista
camera {
  location <0,0,-20>
  look_at <0,0,0>
  angle 40
}

// luci
light_source { 10*<-3,9,-10> color rgb 1.2 }
light_source { 10*<3,9,-10> color rgb 1.2 }

// sfondo sfumato
sky_sphere {
  pigment {
    gradient y
    color_map {
      [ 0.4  color rgb <0.3,0.5,0.9> ]
      [ 0.6  color rgb <0.3,0.3,0.3> ]
    }
    scale 2
    translate y
  }
}

// Titolo
text {
  ttf "arial.ttf" "Elica sul toro" 0.2, 0
  
  no_shadow
  pigment { White }
  
    
  translate <-3,3,-4>
}


#declare Axis = union {
  cylinder {
    <0,-4,0>,<0,4,0>,0.1 
    pigment {
      gradient y
      color_map {
        [0.5 Orange]
        [0.5 White]
      }
      scale 2
      
    }
  }
  cone {<0,4,0>,0.2,<0,5,0>,0}
  texture {Silver_Metal}
}

// Modello (tutto insieme in modo da poterlo
// facilmente ruotare)

union {

  // assi
  object {Axis}
  object {Axis rotate 90*x}
  object {Axis rotate -90*z}

  // nomi degli assi
  text {
    ttf "arial.ttf" "x" 0.1, 0  
    no_shadow
    pigment { White }  
    rotate -180*y    
    scale 0.8
    translate <3.5,0.2,0>
  }
  text {
    ttf "arial.ttf" "z" 0.1, 0  
    no_shadow
    pigment { White }  
    rotate -90*y    
    scale 0.8
    translate <0,0.2,3.5>
  }
  text {
    ttf "arial.ttf" "y" 0.1, 0  
    no_shadow
    pigment { White }  
    rotate -90*y    
    scale 0.8
    translate <0.0,3.5,0.2>
  }


  // piano xz
  box {
    -1,1 scale <4,0.001,4>
    pigment {
      checker 
        Orange transmit 0.8 
        White transmit 0.9 
        translate 0.5*y 
        // se non faccio cosi' la faccia inferiore del box assume
        // colori opposti a quelli della faccia superiore
    }
  }


  // curva parametrica realizzata con tante palline
  union {
    #local R0 = 2; // raggio maggiore del toro
    #local R1 = 1; // raggio minore del toro
    #local M = 13; // numero di "spire"
    #local N = 5000; // numero di palline
    #local I = 0;
    #while(I<N)
  
      #local T = I/(N-1);  // T va da 0 a 1. E' il parametro della curva parametrica
  
      #local Phi = 2*pi*T; // movimento di "rivoluzione" attorno all'asse y
      #local Theta = Phi*M; // movimento di "rotazione" attorno al toro
    
      #local Rxz = R0 + R1 * cos(Theta);
      #local Y = R1 * sin(Theta);
      #local X = Rxz * cos(Phi);
      #local Z = Rxz * sin(Phi);
    
      #local R2 = 0.01+0.09*4*T*(1-T); // il raggio delle palline cambia: piccolo-grande-piccolo

      // la sferetta I-esima  
      sphere {<X,Y,Z>, R2 }

      #local I=I+1;
    #end
    
    texture {Brass_Metal}
  }
  
  // sistemo il modello (assi+etichette+piano xz+curva)
  translate -y
  rotate 120*y
  rotate -30*x
  
} // fine del modello