// 
// es2.pov
//
// Un triangolo costruito con cilindri e sferette
//
// Gian Marco Todesco :: todesco@toonz.com
// per il Liceo Copernico, 6 novembre 2009
//


#include "colors.inc"
#include "textures.inc"

// coordinate dei vertici del triangolo
// (faccio in modo che sia equilatero: calcolo l'altezza
// con il teorema di pitagora. sqrt() calcola la radice quadrata)
#declare H = sqrt(3);
#declare P0 = <-1,0,0>;
#declare P1 = < 1,0,0>;
#declare P2 = < 0,H,0>; 

// raggio delle sfere che rappresentano i vertici 
// e dei cilindri che rappresentano gli spigoli
#declare Ra = 0.2;
#declare Rb = 0.07;


#declare Triangolo = union { // il triangolo e' un unione...

  union { // ... di 3 vertici ...
    sphere {P0,Ra}
    sphere {P1,Ra}
    sphere {P2,Ra}
    texture {Gold_Metal} // ... dorati ...
  }
  union { // ... e tre spigoli ...
    cylinder {P0,P1,Rb}
    cylinder {P1,P2,Rb}
    cylinder {P2,P0,Rb}
    texture {Silver_Metal} // ... argentei
  }
    
} 


// dispongo i triangoli nella scena
object { Triangolo translate <-1,0,0>}
object { Triangolo translate < 1,0,0>}
object { Triangolo translate < 0,-H,0>}
    
object { Triangolo translate <-3,-1,1> }
object { Triangolo translate < 0,-1,1> }
object { Triangolo translate < 3,-1,1> }


// pavimento
plane {
  y,-3
  pigment { White }
}

// cielo
background { SkyBlue }


// telecamera virtuale 
camera {
  location <0,3,-10>
  look_at <0,0,0>
  angle 45
}

// luci
light_source {
  <5,20,-5> color 1
}