// 
// es4.pov
//
// Una quasi-zucca di halloween
//
// Gian Marco Todesco :: todesco@toonz.com
// per il Liceo Copernico, 6 novembre 2009
//

#include "colors.inc"
#include "textures.inc"


// parametri della "faccia"
#declare Occhio_X = 0.3;
#declare Occhio_Y = 0.3;
#declare Occhio_Z = 0.0;
#declare Occhio_R1 = 0.2;

#declare Mostro = union {

  difference {
    // superficie esterna
    sphere {<0,0,0>,1 pigment {Orange}}
    
    union {    
      // superficie interna
      sphere {<0,0,0>,0.8 pigment {Orange}}
      // occhio destro
      cylinder {
        <-Occhio_X,Occhio_Y,-4>,
        <-Occhio_X,Occhio_Y,0>,
        Occhio_R1 
      }
      // occhio destro
      cylinder {
        <Occhio_X,Occhio_Y,-4>,
        <Occhio_X,Occhio_Y,0>,
        Occhio_R1 
      }
      // bocca
      difference {
        cylinder { <0,0,0>,<0,0,-4>,0.6 }
        cylinder { <0,0,0>,<0,0,-4>,0.6 translate <0,0.3,0> }
      }
      // colore delle superfici interne
      pigment {LimeGreen}
    }
  }
  
  // pupilla occhio sinistro
  sphere {< Occhio_X,Occhio_Y,-.3>,.1 pigment {Blue}}
  // pupilla occhio destro
  sphere {<-Occhio_X,Occhio_Y,-.3>,.1 pigment {Blue}}

  // luce interna
  light_source {<0,0.7,0.2> color 1}
}

// dispongo i mostri
object {Mostro}
object {Mostro translate <-2.5,0,0> }
object {Mostro translate < 2.5,0,0> }
object {Mostro translate <-1.25,2,0> }
object {Mostro translate < 1.25,2,0> }


// pavimento
plane {y,-1 pigment { rgb <1,1,1> }}

// cielo
background { SkyBlue }

// telecamera virtuale 
camera {
  location <0,2.5,-10>
  look_at <0,1,0>  
  angle 45
}

// luce
light_source {
  <40,20,-5> color 1
}