// 
// es6.pov
//
// catena
//
// Gian Marco Todesco :: todesco@toonz.com
// per il Liceo Copernico, 13 novembre 2009
//

#include "colors.inc"
#include "textures.inc"

camera {
  location 2*<-2,3,-3>
  look_at <-0.5,0,0>
  angle 40
}

light_source { 10*<5,6,-6> color rgb 2.5 }

// pavimento
plane { 
  y,-1 
  pigment {
    checker Orange White
  }
}

// anello di catena, costituito da due semi-tori e due cilindri
#declare ChainRing = union {
  #local R0 = 0.4;   // semi-distanza fra i cilindri = raggio principale del toro
  #local R1 = 0.15;  // semi-spessore = raggio minore del toro
  #local D = 0.26;    // semi-distanza fra i due semi tori
  // Nota: la lunghezza complessiva dell'anello di catena
  // e' 2*(D+R0)
  #local HalfRing = difference {torus {R0,R1 } plane {x,0}}
  // semi-toro di dx
  object {HalfRing translate D*x}
  // semi-toro di sx
  object {HalfRing rotate 180*y translate -D*x}
  // cilindri di collegamento
  cylinder {-D*x,D*x,R1 translate -R0*z }
  cylinder {-D*x,D*x,R1 translate  R0*z }
  // texture
  texture {Silver_Metal}
}

// catena, formata da N anelli
#declare Chain = union {
  #local N = 7; // numero di anelli 
  #local D = 1.0; // distanza fra i centri di due anelli consecutivi
  #local I = 0;
  #while(I<N)  
    object {ChainRing translate (I-(N-1)/2)*D*x rotate I*90*x }
    #local I = I + 1;  
  #end
}

// piazzo la catena
object {Chain translate -0.6*y }