// 
// es7.pov
//
// specchio
//
// Gian Marco Todesco :: todesco@toonz.com
// per il Liceo Copernico, 13 novembre 2009
//

#include "colors.inc"
#include "textures.inc"

camera {
  location 2*<-2,3,-3>
  look_at <-0.5,0,0>
  angle 40
}

light_source { 10*<5,6,-6> color rgb 1.5 }

// pavimento
plane { 
  y, 0 
  pigment {
    checker color rgb 1.0, color rgb 0.9 
    scale 2
    rotate 30*y
  } 
} 


// mostro
#declare Mostro = union {
  // parametri della "faccia"
  #local Occhio_X = 0.3;
  #local Occhio_Y = 0.3;
  #local Occhio_Z = 0.0;
  #local Occhio_R1 = 0.2;

  difference {
    // superficie esterna
    sphere {<0,0,0>,1 pigment {Orange}}
    
    union {    
      // superficie interna
      sphere {<0,0,0>,0.9 pigment {Orange}}
      // occhio destro
      cylinder {
        <-Occhio_X,Occhio_Y,-4>,
        <-Occhio_X,Occhio_Y,0>,
        Occhio_R1 
      }
      // occhio destro
      cylinder {
        <Occhio_X,Occhio_Y,-4>,
        <Occhio_X,Occhio_Y,0>,
        Occhio_R1 
      }
      // bocca
      difference {
        cylinder { <0,0,0>,<0,0,-4>,0.6 }
        cylinder { <0,0,0>,<0,0,-4>,0.6 translate <0,0.3,0> }
      }
      // colore delle superfici interne
      pigment {LimeGreen}
    }
  }
  
  // occhio
  #local Eye = sphere {
    0,0.1 
    texture {
      pigment {Blue} 
      finish { ambient 0.6 diffuse 0.6 }
    }
  }
  // pupilla occhio sinistro
  object { Eye translate < Occhio_X,Occhio_Y,-0.6>}
  // pupilla occhio destro
  object { Eye translate <-Occhio_X,Occhio_Y,-0.6>}

  // luce interna
  light_source {<0,0.7,0.2> color 1}
}

// dispongo i mostri
object {Mostro scale 0.6 rotate 80*y translate <1,1,-1>}
object {Mostro scale 0.6 rotate 180*y translate <-1,1,-2>}


// specchio
union {
  #local Lx = 4; 
  #local Ly = 2;
  
  // parte riflettente
  box { 
    -0.5,0.5
    scale <Lx,Ly,0.05>
    texture {
      pigment {rgb 0}
      finish {
        reflection 1
        diffuse 0
        ambient 0
      }
    }
  }
  
  // cornice
  difference {
    box {-0.5,0.5 scale <Lx+0.1,Ly+0.1,0.1> } 
    box {-0.5,0.5 scale <Lx,Ly,1> }
    texture {
      Yellow_Pine 
      scale 2
      rotate 50*y
    }     
  }
  
  // piedi di appoggio
  union {
    #local X = Lx*0.3;
    #local Cyl = cylinder {<0,-0.5*Ly,0>,<0,-5,0>,0.03}
    object {Cyl  translate -X*x}
    object {Cyl  translate  X*x}
    texture {Silver_Metal}
  }
  translate y*1.5
}